= СУММ ( ИНДЕКС( данные ; 0 ; ПОИСКПОЗ( величины ; заголовок ; 0 )))
Для того, чтобы найти и вернуть сумму столбца, вы можете использовать формулу, основанную на ИНДЕКС, ПОИСКПОЗ и СУММ функций.
В примере формула в I7 равна:
= СУММ(ИНДЕКС( C5: F11; 0; ПОИСКПОЗ( I6 ; C4: F4 ; 0 )))
Ядро этой функции использует функции ИНДЕКС и ПОИСКПОЗ особым образом, чтобы вернуть полный столбец вместо одного значения.
Функция ПОИСКПОЗ используется для того, чтобы найти правильный номер столбца в I6:
ПОИСКПОЗ( I6 ; C4: F4 ; 0 )
ПОИСКПОЗ возвращает 2 внутри функции ИНДЕКС в качестве аргумента номер_столбца, где массив установлен в диапазоне С5: F11.
Поиск всего столбца
= ИНДЕКС( данные ; 0 ; ПОИСКПОЗ( значение ; заголовки ; 0 ))
Для поиска и извлечения всего столбца, вы можете использовать формулу, основанную на функциях ИНДЕКС и ПОИСКПОЗ. В примере используется формула для поиска всех результатов H7:
=ИНДЕКС(C5:F8;0;ПОИСКПОЗ(H6;C4:F4;0))
Суть: использовать ПОИСКПОЗ, чтобы определить индекс столбца, а затем ИНДЕКС, чтобы получить весь столбец, приравняв номер строки к нулю.
Поиск всей строки
= ИНДЕКС( данные; ПОИСКПОЗ( значение ; массив ; 0 ); 0 )
Для поиска и извлечения всей строки, можно использовать ИНДЕКС и ПОИСКПОЗ функции. В приведенном примере формула, используемая для поиска всех значений для Центрального региона:
= ИНДЕКС( C5: F8 ; ПОИСКПОЗ( H5 ; B5: B8 ; 0 ); 0 )
Суть: использовать ПОИСКПОЗ, чтобы определить индекс строки, а затем ИНДЕКС, чтобы получить всю строку, приравняв номер столбца к нулю.
Поиск наименьшего значения
= ИНДЕКС( диапазон; ПОИСКПОЗ( МИН(величины ); величины; 0 ))
Для поиска информации, связанной с наименьшим значением в таблице, вы можете использовать формулу, основанную на ИНДЕКС, ПОИСКПОЗ и функции МИН.
В примере формула используется для определения имени исполнителя с низким предложением. Формула в F6 является:
= ИНДЕКС( B5: B9 ; ПОИСКПОЗ( МИН( C5: C9 ); C5: C9 ; 0 ))
Поиск стоимости товара или услуги
= ВПР ( продукт ; таблица ; столбец ; ЛОЖЬ)
Если у вас есть список продуктов или услуг (или связанные с ними варианты), с соответствующими затратами, вы можете использовать ВПР, чтобы найти и получить стоимость для конкретного варианта.
В примере формула в ячейке F5 является:
=ВПР(E5;B4:C6;2;0)
Эта формула использует значение ячейки E6 для поиска и извлечения правильной стоимости в диапазоне B5: C7.
Если ВПР находит соответствующее значение, связанные с этим расходы будут извлечены из 2-го столбца (столбец C). Если совпадение не найдено, ВПР возвращает #Н/A ошибку.
Поиск с именем переменной
= ВПР( величина; ДВССЫЛ( » ‘» & листов & «‘!» & «Диапазон» ); столбец; 0 )
Чтобы создать поиск с именем переменной листа, вы можете использовать функцию ВПР вместе с функцией ДВССЫЛ.
В примере формула в С5:
= ВПР ($B5 ; ДВССЫЛ( » ‘» &C$4 & «‘!» & «B5: C11»); 2; 0 )